PDA

View Full Version : Animated optical illusion...can ya do it?!?


ToddziLLa
07-02-2003, 07:55 PM
I know I have not the skills to create something like this...but I wanna see what you guys come up with. I'm looking for an animated optical illusion...no more than 40 or 50 lines. You can use lines, dots, or whatever your creative little brains can think of. I look forward to see what you all come up with!

pom
07-03-2003, 10:54 PM
Errr... WHA'??

annexion
07-04-2003, 10:42 PM
I second that Wha'??

Perhaps you could elaborate, and maybe even show us an example.

webguy
07-07-2003, 01:34 PM
You are getting sleepy!! Very, very sleepy!


_global.levelCount=1;
function createBox () {
newBox = _root.createEmptyMovieClip("box"+levelCount, levelCount++);
newBox.lineStyle(1);
newBox.lineTo(25,0);
newBox.lineTo(25,25);
newBox.lineTo(0,25);
newBox.lineTo(0,0);
newBox._x = Stage.width/2;
newBox._y = Stage.height/2;
newBox.onEnterFrame = function () {
if(this._xscale == 1000) {
this.removeMovieClip();
} else {
this._xscale+=10;
this._yscale+=10;
this._x-=1.2;
this._y-=1.2;
}
}
}
createBoxID = setInterval(this, "createBox", 500);

spot
07-07-2003, 10:00 PM
That cool? I will oneday be able to do things like that.

farafiro
07-08-2003, 06:21 AM
may I add something to webguy code so it doesn't jump (for removing the MCs)_global.levelCount=1;
function createBox () {
newBox = _root.createEmptyMovieClip("box"+levelCount, levelCount++);
newBox.lineStyle(1);
newBox.lineTo(25,0);
newBox.lineTo(25,25);
newBox.lineTo(0,25);
newBox.lineTo(0,0);
newBox._x = Stage.width/4;
newBox._y = Stage.height/4;
newBox.onEnterFrame = function () {
if(this._xscale == 1000) {
this.removeMovieClip();
} else {
this._xscale+=10;
this._yscale+=10;
this._x-=1.2;
this._y-=1.2;
this._alpha -=this._xscale*.005 //**** Just this
}
}
}
createBoxID = setInterval(this, "createBox", 500);

webguy
07-08-2003, 12:26 PM
thats cool farafiro.. I would never have thought of that code. I really really suck at math..used to be good at it in high school, but I guess all the malted hops and bong resin killed those brain cells long ago :). But I am learning once again, many thanks to the reply you posted to my Flash Math Thread. A little out of my league but if I read it 10x over I should understand it sooner or later. :D

farafiro
07-08-2003, 12:30 PM
read the first line i wrote

McGiver
07-08-2003, 04:36 PM
felt free to change your one, but it's still your idea

global.levelCount = 1;
function createBox() {
newBox = _root.createEmptyMovieClip("box"+levelCount, levelCount++);
newBox.lineStyle(1, 0x000000);
newBox.lineTo(-25, 0);
newBox.lineStyle(1, 0x333333);
newBox.lineTo(-25, -20);
newBox.lineTo(0, -20);
newBox.lineTo(0, 0);
if (Key.isDown(Key.LEFT)) {
_root.c = _root.c+3;}
if (Key.isDown(Key.RIGHT)) {
_root.c = _root.c-3;}
newBox._x = Stage.width/4+c;
newBox._y = Stage.height/4;
newBox.onEnterFrame = function() {
if (this._xscale == 3000) {
this.removeMovieClip();
} else {
this._xscale += 10
this._yscale += 10
this._x += 1.4
this._y += 0.9
this._alpha -= this._xscale*.001;}}}
createBoxID = setInterval(this, "createBox", 200);
when I first saw it i thought of driving through a tunnel! I just made the road not that straight as it was!

<edit> :( the first one was a bit buggy! so I changed the code! Press Left and right, to move the road </edit>

magicwand
07-08-2003, 06:46 PM
global.levelCount = 1;
var neg=1
function createBox() {
newBox = _root.createEmptyMovieClip("box"+levelCount, levelCount++);
newBox.lineStyle(1, 0x000000);
newBox.lineTo(-25, 0);
newBox.lineStyle(1, 0x333333);
newBox.lineTo(-25, -20);
newBox.lineTo(0, -20);
newBox.lineTo(0, 0);
newBox.onEnterFrame = function() {
if (Math.abs(this._xscale) > 200) {
this.removeMovieClip();
neg=(-1)*neg;
} else {
trace(Number(neg)*4)
this._xscale =this._yscale +=Number(neg)*4;
}
this._x += Math.ceil(Math.random()*10-3)
this._y += Math.ceil(Math.random()*10-3)
this._rotation+=Math.ceil(Math.random()*10)
}}
createBoxID = setInterval(this, "createBox", 100);

i tried to change the code but...didnt get much..
my failure.

webguy
07-08-2003, 07:18 PM
McGiver that code actually looks like a tunnel..that is kewl. Gonna make a few changes see what I can get outta yer code.

webguy
07-08-2003, 07:30 PM
now it really looks like a tunnel!


global.levelCount = 1;
function createBox() {
newBox = _root.createEmptyMovieClip("box"+levelCount, levelCount++);
newBox.lineStyle(1, 0x000000);
newBox.lineTo(-25, 0);
newBox.lineStyle(1, 0x333333);
newBox.lineTo(-25, -20);
newBox.curveTo(-12.5,-30,0, -20);
newBox.lineTo(0, 0);
if (Key.isDown(Key.LEFT)) {
_root.c = _root.c+3;}
if (Key.isDown(Key.RIGHT)) {
_root.c = _root.c-3;}
newBox._x = Stage.width/2+c;
newBox._y = Stage.height/2;
newBox.onEnterFrame = function() {
if (this._xscale == 3000) {
this.removeMovieClip();
} else {
this._xscale += 10
this._yscale += 10
this._x += 1.4
this._y += 0.9
this._alpha -= this._xscale*.001;}}}
createBoxID = setInterval(this, "createBox", 200);


took out mouse code, it sucked, use up & down to speed up slow down your vehicle :D


global.levelCount = 1;
function createBox() {
newBox = _root.createEmptyMovieClip("box"+levelCount, levelCount++);
newBox.lineStyle(1, 0x000000);
newBox.lineTo(-25, 0);
newBox.lineStyle(1, 0x333333);
newBox.lineTo(-25, -20);
newBox.curveTo(-12.5,-30,0, -20);
newBox.lineTo(0, 0);
if (Key.isDown(Key.LEFT)) {
_root.c = _root.c+3;}
if (Key.isDown(Key.RIGHT)) {
_root.c = _root.c-3;}
if (Key.isDown(Key.UP)) {
_root.s = _root.s+3;}
if (Key.isDown(Key.DOWN)) {
_root.s = _root.s-3;}
newBox._x = Stage.width/2+c;
newBox._y = Stage.height/2;
newBox.onEnterFrame = function() {
if (this._xscale == 3000) {
this.removeMovieClip();
} else {
this._xscale += 10+s
this._yscale += 10+s
this._x += 1.4
this._y += 0.9
this._alpha -= this._xscale*.001;}}}
createBoxID = setInterval(this, "createBox", 200);

pom
07-09-2003, 04:22 PM
I did this some time ago for kirupa's footer contest:

(sorry if it's redundant, I haven't been able to look at the other entries).// Most code written by Zemax
cs = function (r, x, y) {
this.createEmptyMovieClip("S"+z, (++z));
var M = this["S"+z];
M._x = x;
M._y = y;
for (var i=0; i<250; i++) {
var a = i/8 * 1.5707963267948966192313216916398;
var x = 1/5 * i * Math.cos(a);
var y = 1/5 * i * Math.sin(a);
var c = Math.round(255 * i / 500);
M.lineStyle(5, (c<<16) + (c<<8) + c);
M.lineTo(xo+x, yo+y, x, y);
var xo = x;
var yo = y;
}
M.onEnterFrame = function () {
this._rotation += r;
}
}
cs( 10, 50, 30);
this.createTextField("T", 1000, 130, 25, 300, 20);
//T.embedFonts = true;
var tf = new TextFormat();
tf.size = 8;
tf.font = "FFF Galaxy";
tf.selectable = false;
tf.color = "0";
T.text = "You are under control";
T.setTextFormat(tf);

farafiro
07-10-2003, 06:25 AM
this was made for Bit's famouse contest last Sept (2002)x = y=0;
r = 25;
angle = 0;
onEnterFrame = function () {
angle++;
for (i=0; i<75; i++) {
dot = _root.createEmptyMovieClip("d"+i, i*-10);
dot.lineStyle(3, 0xc0c0c0, 100);
dot.lineTo(1, 1);
iAngle = i*angle*(Math.PI/360);
dot._x = x+r+i*Math.cos(iAngle);
dot._y = y-r-i*Math.sin(iAngle);
dot._xscale = dot._yscale=i*2;
dot._alpha = i*2;
}
};
//this piece isn't mine
beginFill(0x000066, 100);
for (var i = 0; i<5; i++) {
this[i == 0 ? "moveTo" : "lineTo"](i%4<2 ? -Stage.width/2 : _x=Stage.width/2, i%4%3 == 0 ? -Stage.height/2 : _y=Stage.height/2);
}

webguy
07-10-2003, 12:49 PM
very nice, sooner or later I might grasp cos and sin then it's all over from there :). I got the concepts just can't apply the math... :mad:

McGiver
07-10-2003, 01:03 PM
wow, this blue thing is really impressing! Wa had a party in school today, and i arrived at home with some(/a lot of) alcohol in my veins, and sat in front of my PC staring at those crazy points for a while! :eek:

subquark
07-10-2003, 01:15 PM
I'm looking for an animated optical illusion take a shaker, cracked ice, gin, vermouth (or the thought of it), shake, pour into chilled cocktail glass, add olives and repeat until you obtain the illusion desired. much easier than all that code nonsense! cheers!

pom
07-13-2003, 07:14 AM
My implementation of the tunnel, in 25 lines :) (try it with a dark background) /*** pom for AS.org ***/
/*** Set up the perspective ***/
oPt = [ Stage.width / 2, Stage.height / 2 ] ;

/*** Set up the box ***/
this.createEmptyMovieClip( "box", -50 )._visible = 0 ;
W = 20 ;
aPt = [ [-W,W],[-W,-W],[W,-W],[W,W],[-W,W] ] ;
box.lineStyle( 0, 0xFF0000, 100 ) ;
box.moveTo( aPt[0][0], aPt[0][1] ) ;
for ( var j in aPt ) box.lineTo( aPt[j][0], aPt[j][1] ) ;

/*** Set up the functions ***/
function createBox() {
myInit = { x:px, y:py, z:500, _alpha:30 } ;
newBox = box.duplicateMovieClip( "b" + count, count++, myInit ) ;
newBox.onEnterFrame = function() {
if ( this._alpha < 95 ) this._alpha += 5 ;
this.z -= 10 ;
var scale = 300 / ( 300 + this.z ) ;
this._xscale = this._yscale = 100 * scale ;
this._x = oPt[0] + this.x * scale ;
this._y = oPt[1] + this.y * scale ;
this.x *= .9 ;
this.y *= .9 ;
this._rotation += 1 ;
if ( this.z < -300 ) this.removeMovieClip() ;
}
}

/*** Set up the Key check ***/
this.onEnterFrame = function () {
px += ( Key.isDown(Key.RIGHT) - Key.isDown(Key.LEFT) ) * 2 ;
py += ( Key.isDown(Key.DOWN) - Key.isDown(Key.UP) ) * 2 ;
}
createBoxID = setInterval(this, "createBox", 200);pom :cool:

farafiro
07-13-2003, 07:25 AM
seems there are some bugs POM
what is this also??
myInit = { x<img src="images/smilies/tongue.gif" border="0" alt="">x, y<img src="images/smilies/tongue.gif" border="0" alt="">y, z:500, _alpha:30 } ;

pom
07-13-2003, 12:22 PM
A smilie appeared in the code, it should be OK now. Thanks :)

farafiro
07-14-2003, 02:55 AM
wow, this is cool POM

subquark
07-14-2003, 08:02 AM
very cool! excellent!

webguy
07-14-2003, 09:04 AM
I like that pom, I feel like a jedi knight ;)

pom
07-14-2003, 10:54 AM
That's the spirit! :D Though if I trust your picture, you look more like the Emperor than Luke Skywalker...

senocular
07-14-2003, 11:27 AM
So far nothing seems very optical illusional - just some trippy moving boxes :rolleyes: :D

We should all take a deep breath and invest some time in looking at some escher work :cool:

Heres something that is a little more illus-ie:
pyramids = {a:{mc: this.createEmptyMovieClip("pa",1),points:[[0,-60,100],[50,30,100],[-50,30,100],[0,0,0]]},b:{mc:this.createEmptyMovieClip("pb",2),points:[[0,0,0],[0,-60,-100],[50,30,-100],[-50,30,-100]]}};
MovieClip.prototype.draw = function(x1,y1,x2,y2,x3,y3,xoff,yoff){
if (((y2-y1)/(x2-x1)-(y3-y1)/(x3-x1)<0)^(x1>x2^x1>x3)==Key.isDown(1)){
this.beginFill(0xddff00,100);this.lineStyle(1,0x99 bb00,100);
this.moveTo(x1+xoff,y1+yoff);this.lineTo(x2+xoff,y 2+yoff);this.lineTo(x3+xoff,y3+yoff);this.lineTo(x 1+xoff,y1+yoff);
this.endFill();}};
Array.prototype.ft = function(ax,ay,az){
var t=[],x,y,z,calc={cx:Math.cos(ax),sx:Math.sin(ax),cy:Ma th.cos(ay),sy:Math.sin(ay),cz:Math.cos(az),sz:Math .sin(az)};
for (i=0;i<7;i++){
x={y:this[i][1]*calc.cx-this[i][2]*calc.sx,z:this[i][1]*calc.sx+this[i][2]*calc.cx};
y={x:this[i][0]*calc.cy+x.z*calc.sy,z:x.z*calc.cy-this[i][0]*calc.sy};
z={x:y.x*calc.cz-x.y*calc.sz,y:y.x*calc.sz+x.y*calc.cz,s:500/(500+y.z)};
t[i]=[z.x*z.s,z.y*z.s];
if (!i||y.z<t.d) t.d=Math.round(y.z);}
return t;};
Array.prototype.fd = function(mc){
mc.clear();
mc.draw(this[2][0],this[2][1],this[1][0],this[1][1],this[0][0],this[0][1],150,150);
mc.draw(this[0][0],this[0][1],this[3][0],this[3][1],this[2][0],this[2][1],150,150);
mc.draw(this[0][0],this[0][1],this[1][0],this[1][1],this[3][0],this[3][1],150,150);
mc.draw(this[1][0],this[1][1],this[2][0],this[2][1],this[3][0],this[3][1],150,150);
mc.swapdepths(-this.d);};
this.onEnterFrame = function(){
pyramids.a.points.ft((this.ax+=(this._ymouse-150)/5000),(this.ay+=(this._xmouse-150)/5000),this.az).fd(pyramids.a.mc);
pyramids.b.points.ft(this.ax,this.ay,this.az).fd(p yramids.b.mc);};
granted, it cheats a little bit to make 25 lines, but I think the illusion is there - or atleast a deceptive aspect of
imagery which may perplex the mind a tingle. Mouse movement controls rotation; hold the mouse down to see the
'real' representation. Basically this is just reversing depth relation and visible faces of the pyrmaids.

pom
07-14-2003, 12:51 PM
Well, I was hoping that hurting people's eyes could be considered an optical illusion :rolleyes:

And what in the world is that line supposed to mean, Sen??? :Dif (((y2-y1)/(x2-x1)-(y3-y1)/(x3-x1)<0)^(x1>x2^x1>x3)==Key.isDown(1)){

senocular
07-14-2003, 01:33 PM
((y2-y1)/(x2-x1)-(y3-y1)/(x3-x1)<0)^(x1>x2^x1>x3) determines if a triangle (polygonal plane) is visible or not - visible in the sense that we're dealing with single sided polygons where if that equation above is true, then you're looking at the 'front' of the triangle polygon defined by x1,y1,x2,y2,x3,y3 and where if false, you are looking at the 'back' (it basically just compares spacial relationships between the three points with each other and the slopes of 2 line segments between them). The back of a single sided polygon would be invisible and therefore wouldnt be drawn, which is why that is used in the if condition for rendering with beginFill and linetos.

The == Key.isDown(1) checks to see whether that condition is equivalent to the left mouse button being pressed. Key.isDown(1) is true when the mouse button is pressed, false when not. So, when Key.isDown(1) is false and the mouse button isnt being pressed, the visiblility equation is compared to false so imagery is drawn when the visibility equation is false or when we're seeing the backs of the polygons instead of the fronts. Pressing and holding the left mouse button makes the comparison to true so visibility is then compared with true (as it is intended) so the 'normal' visibility is seen, or the just the fronts of the polygons.

:)

farafiro
07-15-2003, 03:39 AM
wow Seno
this code should be in the competition not the pyramids lol
it hurts the brain more than the eye

spot
07-16-2003, 07:04 AM
I love watchinh you guys show off your talents.!
Curiosity, are you all maths minds or just talented.?

senocular
07-16-2003, 07:13 AM
:D well knowing math is part of it but I don't think many of us consider ourselves to be 'Math Minds' (of course I can't speak for everyone when I say that). Sure, talent is involved, but a lot is just a reflection of our love and devotion to Flash. The more time you spend using it and familiarizing yourself with how it works and what it can do, the more you can do with it. There are a lot of ... talented ;) people here who just enjoy Flash and that is seen in threads like these. Its not only a sign of skill but its a way to just have fun and possibly learn something in the process. Even if you don't personally learn anything, other people might. :cool:

pom
07-16-2003, 08:42 AM
Is that what "they" call backface culling (sp?)?

And that's pretty clever, but unfortunately 3-dimensional geometry has never been my favorite subject in the classrooms...

Spot >> For me, I'd say it's pure talent :D

senocular
07-16-2003, 09:10 AM
Originally posted by pom
Is that what "they" call backface culling (sp?)?

yup, thats it ;)

dr.swank
07-18-2003, 04:29 AM
well folkage, I am not sure this counts, but the effect here is that the lines seem to be drawn twice, once in grey, and then in pink. Not very complicated, but I thought I might post it for novilty sake.


/* optical illusion by Julian Sander
in 25 lines or less
simple, but I thought you might enjoy
*/
function drawShape() {
//create new empty clip
_root.createEmptyMovieClip("api_mc"+depth, depth++);
//create random number to generate quantity of points (at leaset 3)
r = random(15)+3;
// loop through points
for (i=0; i<=r; i++) {
//in each iteration create a new x and y position
rx = random(400);
ry = random(400);
//create random line thickness and alpha
_root["api_mc"+depth].lineStyle(random(10), 0x999999, (random(50)+50));
// make the drawn line a curve if these conditons are met
if (i<r) {
if (r == 3 || r == 5 || r == 9) {
_root["api_mc"+depth].curveTo(rx, ry, ry*3, rx*2);
} else {
trace("i<r");
_root["api_mc"+depth].lineTo(rx, ry);
}
//if this is the last point use the moveTo method to end the line
} else {
_root["api_mc"+depth].moveTo(rx, ry);
}
}
//remove the clips that are older so as to free up the screen
_root["api_mc"+(depth-8)].removeMovieClip();
}
//run the timed loop. using a 5 millisecond flow makes it look as if the lines are drawn in pink...
setInterval(drawShape, 5);

senocular
07-20-2003, 10:19 PM
wow thats pretty crazy dr.swank :)

dr.swank
07-21-2003, 05:51 AM
theres more:


http://burbacher.org/api2.html (http://)
and
http://burbacher.org/api3.html (http://)
and
http://burbacher.org/api4.html (http://)
and
http://burbacher.org/api5.html

they are all based roughly on the same code. if anyone is interested I can post the scripts.

cheers, doc

freddycodes
07-21-2003, 11:29 PM
I have a few weird ones I did a while ago, not too much of an optical illusion but what the hey.


http://www.irq11.com/~louie/portfolio/swf/colored_lines.swf

//Click in the movie on this one
http://www.irq11.com/~louie/portfolio/swf/etch-a-sketch_colored_auto5.swf

http://www.irq11.com/~louie/portfolio/swf/etch-a-sketch_colored_auto4.swf

//Arrow keys
http://www.irq11.com/~louie/portfolio/swf/etch-a-sketch_colored.swf


http://www.irq11.com/~louie/portfolio/swf/random_lines_always_moving_away_pt4.swf

http://www.irq11.com/~louie/portfolio/swf/random_lines_always_growing.swf

//Me flying through the sky
http://www.irq11.com/~louie/portfolio/swf/starfield.swf




I must be bored, sorry to hijack the optical illusion thread, I can't touch senocular's math skills.

retrotron
07-26-2003, 01:29 AM
Ha ha, you flying through the sky . . . I love that one.

senocular
07-26-2003, 07:59 AM
lol thats you in the starfield? lol I didnt even notice it at first and didnt know what retrotron was talking about :D

McGiver
07-26-2003, 02:58 PM
lol! what an effect.

abraham156
08-29-2005, 10:51 PM
yeahh

optical illusion???

www.optical-illusion.org

http://www.optical-illusion.org/pictures/car.jpg

invader
09-14-2005, 08:58 PM
hmm.. this is a real optical illusion (rather than just trippy shapes, etc), BUT it's not animated, like the title implies. before testing CHANGE BG COLOR to black..

z = new Array ( 500 , 400 , 20 ); // Width, Height, Spacing
createEmptyMovieClip("grayLines",0); // create movie to hold gray lines
createEmptyMovieClip("whiteDots",1); // create movie to hold white dots
grayLines.lineStyle(5,0x888888,100); // set gray line properties
for (i=0;i*z[2]<=z[1];i++) { // repeat for each row
grayLines.moveTo(0,i*z[2]); // start horizontal line
grayLines.lineTo(z[0],i*z[2]); } // draw horizontal line
for (i=0;i*z[2]<z[0];i++) { // repeat for each column
grayLines.moveTo(i*z[2],0); // start vertical line
grayLines.lineTo(i*z[2],z[1]); } // draw vertical line
whiteDots.lineStyle(7,0xFFFFFF,100); // set white dot properties
for (i=0;i*z[2]<=z[1];i++) { // repeats for each row
for (j=0;j*z[2]<=z[0];j++) { // then for each column
whiteDots.moveTo(j*z[2],i*z[2]-.25); // start dot
whiteDots.lineTo(j*z[2],i*z[2]+.25); } } // end dot
// 15 lines! 8 )

CMU
09-15-2005, 05:51 PM
It certainly looks animated, although I realise that's exactly the illusion. Nice one!

Headshotz
09-16-2005, 12:04 PM
Take a look at these (http://www.liquidgeneration.com/sabotage/optical_sabotage.asp) just for fun.

Remember to look nice and closely at the end.

invader
09-17-2005, 06:00 AM
this one is also not animated (the best illusions in my opinion are the ones that don't require motion).. it was 15 lines, but i set the background color manually.. so this time, you don't have to change anything in the environment. just copy and paste:

createEmptyMovieClip("BG",0);
BG.beginFill(0x99CC33,100);
BG.moveTo(-23,-23);
BG.lineTo(24*23,-23);
BG.lineTo(24*23,24*23);
BG.lineTo(-23,24*23);
BG.endFill();
createEmptyMovieClip("ellipse",1);
ellipse.lineStyle(2,0x553322,100);
ellipse.beginFill(0x884422,100);
ellipse.moveTo(-10,0);
ellipse.curveTo(-8,-6,0,-6);
ellipse.curveTo(8,-6,10,0);
ellipse.lineStyle(2,0xEEEEEE,100);
ellipse.curveTo(8,6,0,6);
ellipse.curveTo(-8,6,-10,0);
ellipse.endFill();
for (i=0;i<23*23;i++) {
duplicateMovieClip(ellipse,"ellipse"+i,i+2);
_root["ellipse"+i]._x = 24*(i%23);
_root["ellipse"+i]._y = Math.floor(i/23)*24;
_root["ellipse"+i]._rotation = 30*i;}
// 22 lines!

Headshotz
09-18-2005, 09:04 AM
Nice, that looks cool.

Did you check out that link?

farafiro
09-18-2005, 10:36 AM
ahhhhhhhhhh invader
http://www.optical-illusion.org/
.
.
gotcha

Headshotz
09-19-2005, 07:07 AM
Haha,I don't get the last one.

plurdled
09-23-2005, 03:07 PM
I made this a few days ago. Yeah yeah. Not an optical illusion. :P
You need Flash 8 Player, btw.

http://www.pixelharbinger.com/nerd.html

And another one. Kinda Win98 Screen Saver Style hah
http://www.pixelharbinger.com/98.html

cghughes
09-23-2005, 09:47 PM
Thank a bunch Headshotz. My grandpa just had a heart attack and died.

Jeemaneez, scared the crap out of me. Doesn't help that I had my stereo cranked pretty loud too, for some odd reason.

invader
09-30-2005, 10:50 PM
I made this a few days ago. Yeah yeah. Not an optical illusion. :P
You need Flash 8 Player, btw.

http://www.pixelharbinger.com/nerd.html

And another one. Kinda Win98 Screen Saver Style hah
http://www.pixelharbinger.com/98.html
:D :D :D :D :D

i enjoyed staring at those for a while. the glow effect is very impressive. there are a few ways i can think of to accomplish it. how did you do it?

kkxpertise
10-02-2005, 12:08 AM
this.createEmptyMovieClip("draw_mc",getNextHighestDepth());

draw_mc._x=100;
draw_mc._y=100;





button_mc.onRelease = function():Void
{
_root.onEnterFrame = function() {
//var nRandonWidth:Number = Math.random() * 100;

var nRandomAlpha:Number = Math.random() * 100;
// This is for the Alpha of the line.

var nRandomCoorx:Number = Math.random() * 500;
// This is for the Coordinate X of the line.


///////////////////- Actual Run-in -//////////////////////

var nRandomCoory:Number = Math.random() * 200;
// This for the Coordinate Y of the line.

draw_mc.lineStyle(3,0x000000,nRandomAlpha);
/*
I'll throw the Alpha Random where the alpha is to randomize the alpha.
*/

draw_mc.lineTo(nRandomCoorx,nRandomCoory);
// I'll put the Random coordinates here.

}
}


clear_mc.onRelease = function()
{

draw_mc.clear();
// The button clears the action

}

jUST ME SCRIBBING HAHAHA! Not bad for 3 months into AS?

CMU
10-02-2005, 05:24 AM
That doesn't do anything for me unless I remove the first:

button_mc.onRelease = function():Void

which makes sense - at that point there's nothing on the button_mc to actually click yet.

So what's the illusion there? Just looks like random lines to me.

Headshotz
10-02-2005, 07:34 AM
Thank a bunch Headshotz. My grandpa just had a heart attack and died.

Jeemaneez, scared the crap out of me. Doesn't help that I had my stereo cranked pretty loud too, for some odd reason.


LOL

Scared the crap outs me 2 years ago, I have been saving it
for when someone on AS.org makes a thread about optical
illusions :p

plurdled
10-02-2005, 04:04 PM
:D :D :D :D :D

i enjoyed staring at those for a while. the glow effect is very impressive. there are a few ways i can think of to accomplish it. how did you do it?
Just the glow filter in flash 8. i originally made it in mx so at first the glow was simply a copy of the movie clip with the alpha turned down a bit and set to a bright red. but 8 is muuuuch better!

Headshotz
10-03-2005, 02:05 AM
I love Flash 8, less switching between fireworks and flash
to do simple things.