[iOS] Swipe Gesture not working with 2 or more fingers.

[irrelevantjoker]

This function only seems to work on iOS and Android devices if you swipe 1 finger. Anything more than 1 and nothing happens. Any ideas?

Multitouch.inputMode = MultitouchInputMode.GESTURE;
this.addEventListener (TransformGestureEvent.GESTURE_SWIPE, SwipeHandler, false, 0, true);

protected function SwipeHandler(event:TransformGestureEvent):void
        {
                _sliding = true;
                switch(event.offsetX)
                {
                    case 1:
                        slideLeft();
                    break;
            
                    case -1:
                        slideRight();
                    break;
                }
        }

[ASWC]

What do you get when running the supportedGestures() method?

[irrelevantjoker]

gestureZoom
gesturePan
gestureRotate
gestureTwoFingerTap
gestureSwipe

The swipe gesture is called when one finger is swiped. If I use 2 or more fingers, it isn't called.

I'm looking for a way so that any number of fingers swiped at the same time will call the function.

[irrelevantjoker]

After some research I've moved away from the swipe gesture event, and I've gone with the following, it's a little longer, but allows for more customisation.

I've pulled this code out of my app-in-progress, it allows any-finger swiping, but can be edited to isolate 1 to 5 finger swiping.

import flash.ui.Multitouch;
import flash.ui.MultitouchInputMode;
import flash.events.TransformGestureEvent;
import flash.events.TouchEvent;

private var touchMoveID:int = 0; 
private var swipeX:Number;
private var swiped:Boolean = false;

if (Multitouch.supportsGestureEvents) {
    Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT; 
    mc.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin, false, 0, true);
                
}
        
private function onTouchBegin(event:TouchEvent):void
{
    if (touchMoveID != 0) return;
    touchMoveID = event.touchPointID; 
    mc.addEventListener(TouchEvent.TOUCH_MOVE, onTouchMove,false,0,true); 
    mc.addEventListener(TouchEvent.TOUCH_END, onTouchEnd,false,0,true); 
    swipeX = event.stageX;
}
        
private function onTouchMove(event:TouchEvent):void
{
    if (event.touchPointID != touchMoveID || swiped) return;
    var gapX:Number = swipeX - event.stageX;
    if (gapX > 100) {
        swiped = true;
        trace("SWIPED RIGHT");    
    }else if (gapX < -100) {
        swiped = true;
        trace("SWIPED LEFT");
    }
}
        
private function onTouchEnd(event:TouchEvent):void
{
    if (event.touchPointID != touchMoveID) return;
    touchMoveID = 0;
    swiped = false;
}