Scale an Image

[fohanlon]

Hi Guys

I have coded as3 to allow for an image to be uploaded and portionally resized, smoothed etc into a movieclip of a fixed size say 150 x 150.

Once the image is uploaded I have buttons to scale the image + or - using scaleX and scaleY.

Here is where I have the problem.

I want to do a couple of things:

1. Ensure the image uploaded when being scaled up cannot go beyond the 150 pixels size and also when being scaled down it cannot go below a certain size.

2. When scaling how can I ensure the scaled image will always be centred vertical and horizontal in the movieclip.

Thanks for your advice.

F.

[-:)lauri]

Maybe something like this would help:

// To enlarge by pixel
function scaleUpImage():void{
    if(image.width < 150 && image.height < 150){
        image.width += 1;
        image.height += 1;
        centerImage();
    }
}

// To shrink by pixel
function scaleDownImage():void{
    if(image.width > certainSize && image.height > certainSize){
        image.width -= 1;
        image.height -= 1;
        centerImage();
    }
}

// To center the image
function centerImage():void{
    image.x = (movieclip.width - image.width) / 2;
    image.y = (movieclip.height - image.height) / 2;
}

[svenjoypro]

I attached a fla (CS4), here's the code:

import flash.events.MouseEvent;

increase_btn.addEventListener(MouseEvent.CLICK, onIncrease);
decrease_btn.addEventListener(MouseEvent.CLICK, onDecrease);

function onIncrease(evt:MouseEvent):void {
    var inc:Number = .2;
    var max:int = 150;
    
    img_mc.scaleX += inc;
    img_mc.scaleY += inc;
    if (img_mc.width > max) {
        img_mc.scaleX = img_mc.scaleY = 1;
        img_mc.scaleX = img_mc.scaleY = max/img_mc.width;
    }
    if (img_mc.height > max) {
        img_mc.scaleX = img_mc.scaleY = 1;
        img_mc.scaleX = img_mc.scaleY = max/img_mc.height;
        if (img_mc.width > max) {
            img_mc.scaleX = img_mc.scaleY = 1;
            img_mc.scaleX = img_mc.scaleY = max/img_mc.width;
        }
    }
    centerImage();
}

function onDecrease(evt:MouseEvent):void {
    var dec:Number = .2;
    var min:int = 50;
    
    img_mc.scaleX -= dec;
    img_mc.scaleY -= dec;
    if (img_mc.width < min) {
        img_mc.scaleX = img_mc.scaleY = 1;
        img_mc.scaleX = img_mc.scaleY = min/img_mc.width;
    }
    if (img_mc.height < min) {
        img_mc.scaleX = img_mc.scaleY = 1;
        img_mc.scaleX = img_mc.scaleY = min/img_mc.height;
        if (img_mc.width < min) {
            img_mc.scaleX = img_mc.scaleY = 1;
            img_mc.scaleX = img_mc.scaleY = min/img_mc.width;
        }
    }
    centerImage();
}

function centerImage():void {
    img_mc.x = (stage.stageWidth-img_mc.width)/2;
    img_mc.y = (stage.stageHeight-img_mc.height)/2;
}

[fohanlon]

Many thanks Lauri your code worked perfectly for my solution.

[fohanlon]

Many thanks svenjoypro. I combined some of your code with Lauri's.