Collision Testing

[lordoftherock]

hi,
I am able to test if my objects are colliding with eachother but how would i go about testing if it is a topside, bottomside, leftside or rightside. I am using bitmaps to get pixel perfect collision.
thanks

[backshesh]

you have to make a collision sensor for the top bottom left and right side. And when that sensor is activated it activates a code saying the top bottom left and right side where just activated.

Just wondering but what is your method for the collision detection. I am working on a project right now and I am working on a bitmapdata collision detection thing. Just curious.

[mushroom6969]

im interested how would you do this im working on a similar thing

[lordoftherock]

how exactly would i make a collision sensor. When doing collisions for rectangular objects i have just drawn out 4 separate rectangles for top, left, bottom, right and tested for collisions with those, but now for bitmaps that wouldn't work.

My method is essentially what is done here: mikechambers(dot)com/blog/2009/06/24/using-bitmapdata-hittest-for-collision-detection

[lordoftherock]

Anyone?

[abeall]

Mike Chambers example is great, but BitmapData/hitTest is not a good method to determine angle of collision, since it only tells you whether two shapes overlap and doesn't give you any additional information.

One way to determine the angle of a collision is to do a series of hitTestPoint checks in a circle, then take the average vector of all hits in that circle. For instance:

/**
 * Test for a hit against a shape based on a point and radius, 
 * returns the angle of the hit or NaN if no hit.
 */
function hitTestPointAngle(object:Sprite, xPos:Number, yPos:Number, radius:Number, samples:uint = 90):Number {
    const PI2:Number = Math.PI * 2, SAMPLE:Number = 1 / samples;
    var dx:Number, dy:Number, a:Number, tx:Number = 0, ty:Number = 0, hits:int = 0;
    var i:int = samples;
    while(i--){
        a = PI2 * (i * SAMPLE);
        dx = radius * Math.cos(a);
        dy = radius * Math.sin(a);
        if(object.hitTestPoint(xPos + dx, yPos + dy, true)){
            hits++;
            tx += dx;
            ty += dy;
        }
    }
    if(!hits)
        return NaN;
    
    return Math.atan2(ty, tx) * (180 / Math.PI);
}

// Example:
var hitAngle:Number = hitTestPointAngle(walls, player.x, player.y, 15);
if(!isNaN(hitAngle)){
    // move player 5px away from walls
    player.x -= Math.cos(hitAngle * (Math.PI / 180)) * 5;
    player.y -= Math.sin(hitAngle * (Math.PI / 180)) * 5;
}

You could also check out the open source "collision detection kit":
http://code.google.com/p/collisiondetectionkit/

[lordoftherock]

hi thanks so much for that! I don't think i could have done it on my own!
However, the collisions seem to be innacurate:

public function movePlayer(event:Event):void {
//other stuff..
collisions();
}
public function collisions():void { 
 
for(var i:int=0;i<collisionObj.length;i++) { //loop through objects

            
            var hitAngle:Number = hitTestPointAngle(collisionObj[i].mc, player.x, player.y, 15);
            if(!isNaN(hitAngle)){
                // move player 5px away from walls
                player.x -= Math.cos(hitAngle * (Math.PI / 180)) * player.speed*timeDiff;
                player.y -= Math.sin(hitAngle * (Math.PI / 180)) * player.speed*timeDiff;
            }
}
}

it is identifying the collision when the player is no where near the object?
thanks very much!

[abeall]

You would need to set the radius argument to the radius of your player.

Also looping through all your collision objects is not the way to do this. Put all your collision objects in a container and just check once against the container.

[lordoftherock]

ok thanks,
the radius of my player is 7.5px, yet this hasn't solved the problem. Turning off the scrolling in my game seems to make it work slightly better, yet the collisions are still inaccurate. The collisions (which still are being detected far away from the object) seem to make the player move in an orbital motion.

[abeall]

hitTestPoint requires the x and y coordinate to be in stage coordinates. Since your player object is in a container that is being scrolled, the player x and y needs to be convert to stage coordinates:

var point:Point = localToGlobal(new Point(player.x, player.y));
var hitAngle:Number = hitTestPointAngle(collisionObjContainer, point.x, point.y, 15);