How to add a boundary to an object

[Pedz101]

So I created a action script object on the stage. Named the stage document class as movement. The object can move with the keyboard, however, I don't want it to move off stage. The object instance name is square. My question is how do I add a boundary to the object? I've tried the hitTestObject but it doesn't work very well. The stage is 900 by 575.

Note: I am still a newbie so if you can explain to me in details that would be great. thx

[[afz]snickelfitz]

Since you already have the keyboard movement handled, this example uses a draggable object.

import flash.events.*;
import flash.display.*;
import flash.geom.*;

// movieclip on the stage named "object"
var object:MovieClip;
object.addEventListener(MouseEvent.MOUSE_DOWN, drag);
stage.addEventListener(MouseEvent.MOUSE_UP, drop);

// track the clicked movieclip
var target:MovieClip;

// define the draggable boundaries; stroke the boundary
var bounds:Rectangle = new Rectangle(100, 100, stage.stageWidth-200, stage.stageHeight-200);
var g:Graphics = this.graphics;
g.lineStyle(0);
g.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);

function loop(e:Event):void
{
    if (target.x > bounds.right - target.width)
    {
        target.x = bounds.right - target.width;
    }
    if (target.x < bounds.left)
    {
        target.x = bounds.left;
    }
    if (target.y > bounds.bottom - target.height)
    {
        target.y = bounds.bottom - target.height;
    }
    if (target.y < bounds.top)
    {
        target.y = bounds.top;
    }
}

function drag(e:MouseEvent):void
{
    // define target
    target = e.currentTarget as MovieClip;
    target.startDrag();
    
    // check target coordinates on each enter frame event
    addEventListener(Event.ENTER_FRAME, loop);
}

function drop(e:MouseEvent):void
{
    target.stopDrag();
}

[Pedz101]

Thanks for giving an example for drag and drop but then how do I use this for creating the stage a boundary? Also how I use the x and y for the square to make sure it doesn't leave the stage?

[[afz]snickelfitz]

Just make the Rectangle instance the same dimensions as the stage.
ie: var bounds:Rectangle = new Rectangle(0,0,stage.stageWidth,stage.stageHeight);

Everything else is essentially the same.
The rectangle is included here to illustrate the usefulness of the Rectangle class for doing stuff like this. ie: Rectangle has convenient left, right, bottom, top properties as well as a host of useful methods.

BTW, notice that there are virtually no hard-coded numeric properties in this code, which makes it more flexible and universal than using the numbers 900 and 575 to describe the stage boundaries. For all intents and purposes, the actual dimensions of the stage are irrelevant.

One other thing: be sure your concept of the stage is correct.
There is only one Stage instance. The stage dimensions are set in the FLA in the properties panel, along with the stage background color and document frameRate.

Flash Player instance
--Stage instance
----Document Class instance
------stuff you create in Flash

[Pedz101]

Thanks it work =]