dynamic properties

[ddobbs]

What is the proper way of creating dynamic properties in AS3.0? To clarify what I mean, in AS1.0/2.0 I could do something like this...

mcRef=_root.createEmptyMovieClip("mc",1)
mcRef.my_special_property="i am special"
mcRef.my_index=4


What is the equivalent AS3.0 code? And can this be done for Sprites as well as MovieClips? Thanks!

[TomMalufe]

The way you do something like that in AS3 is you extend the Sprite or MovieClip class file.

package {
     import flash.display.Sprite;

     public class Special extends Sprite {
          public var mySpecialProperty:*;
     }
}

It's considered proper to use private vars in a class and then setup getter and setter functions for it. But you don't have to in every case.

[senocular]

MovieClip instances are dynamic in AS3 so you can add dynamic properties to them just as you could in AS2. Some other classes, like Sprite, are not dynamic, however, and you would then have to use a MovieClip instead or some other dynamic alternative (or place your properties in a subclass as demonstrated by Tom)

[panel]

But if you really wanna create variables in runtime you have to create dynamic class

package
{
    public dynamic class MyClass
    {

        public function MyClass()
        {
            
        }
    }
}

[ddobbs]

Thanks fellas. I think I got it working but it doesn't seem proper for some reason. Here's the AS1/2 code followed by the new AS3 code...

propArr=new Array("Red","Coffee","Arizona")

for(i=0;i<propArr.length;i++) {
	
	mcRef=this.createEmptyMovieClip("mc_"+i,i)
	mcRef.my_special_property=propArr[i]
	mcRef.my_index=i
	
	mcRef._x=80*i
	mcRef._y=10
	
	mcRef.beginFill(0xFF0000);
	mcRef.moveTo(0, 0);
	mcRef.lineTo(50, 0);
	mcRef.lineTo(50, 20);
	mcRef.lineTo(0, 20);
	mcRef.endFill();
	
	mcRef.onPress=function() {
		trace([this.my_special_property,this.my_index])
	}
}

new AS3 code in 2 files, main.as:

package {
	import flash.display.Sprite;
	import flash.events.MouseEvent;  

	public class main extends Sprite
	{
		public function main()
		{
			var propArr:Array=new Array("Red","Coffee","Arizona")
			
			for(var i:int=0;i<propArr.length;i++) {
				var scRef:specialContainer = new specialContainer(propArr[i],i);
				scRef.x=80*i
				scRef.y=10				
				scRef.buttonMode=true
				scRef.addEventListener(MouseEvent.MOUSE_DOWN, clickMe)
				addChild(scRef)
				
			}
						
		}
		
		public function clickMe(event:MouseEvent):void {
			trace(event.target.my_special_property+" "+event.target.my_index)
		}		
	}
}

and specialContainer.as:

package {
	import flash.display.Sprite;

	public class specialContainer extends Sprite
	{
		public var my_special_property:String;
		public var my_index:int;
		
		public function specialContainer(p1:String,p2:int)
		{
			graphics.beginFill(0xFF0000)
			graphics.drawRect(0,0,50,50)
			this.my_special_property=p1
			this.my_index=p2
		}
	}
}

Is there some correct way/better way to do this? or just an alternate way?

Thanks again.