Finding What is in a Movieclip

[Djjinn]

in as2 you could do something like

var mc:MovieClip = new MovieClip();
mc.attachMovie("new.swf","mc",0);

for(var x in mc)
    trace(x + ": " + mc[x]);

and that would get you all the contents of a movieclip (properties, objects, and whatever)..

but that lil bit of code doesn't do anything for me in as3? anyone know how i can find what movieclips are on the "stage" of the imported movieclip:

I'm using

var Main:MovieClip = new MovieClip();

btnLoad.addEventListener(MouseEvent.MOUSE_UP, loadSwf);
btnParse.addEventListener(MouseEvent.MOUSE_UP, parseMC);

function loadSwf(e:MouseEvent)
{
	var req:URLRequest = new URLRequest("navBase.swf");
	var ldr:Loader = new Loader();
	ldr.addEventListener(Event.INIT, loadHandler);
	ldr.load(req);
	addChild(ldr);
}

function loadHandler(e:Event)
{	
	Main = e.target.content;	
}

function parseMC(e:MouseEvent)
{
	// this was an attempt of using the movieclip as a DisplayObjectContainer 
	// since it appears to extend that class but it returns 0 children even 
	// though i see some on the stage
	trace(Main.numChildren);
}

[Sleeve]

Hi-

The for...in loop will only propagate properties of a dynamic class.

That old AS2.0 code will work for MovieClips because the MovieClip class is a dynamic class; except it will not return child objects because they are referenced in the DisplayObjectContainer class which is not dynamic.

Also, a display object's "stage" property refers to the Stage of the display object which is also not a dynamic class therefore you cannot use a for...in loop to iterate its properties.

The closest thing you can get to the old AS2.0 functionality on a non-dynamic class is describeType(). Although it still will not return objects or references to objects that may exist in the display list.

You can alternatively write a function that traverses the displaylistcontainer and returns an array of objects within the display list.

protected function traverseDisplayList(dObj : DisplayObjectContainer) : Array
{
    var a : Array = [];
    for (var i : int = 0; i < dObj.numChildren; i++)
    {
        if (dObj.getChildAt(i) is MovieClip) // or whatever...
        {
            a.push(dObj.getChildAt(i));
        }
    }
    return a;
}

[Djjinn]

well it appears I made a few mistakes.

First the Event.COMPLETE isn't called by the loader, but actually called by the Loader.contentLoaderInfo.

var Main; // yes its an untyped object... I'll explain later
var ldr:Loader = new Loader();

btnLoad.addEventListener(MouseEvent.MOUSE_UP, loadSWF);

function loadSWF(e:MouseEvent){

    if(ldr.content != null)
                removeChild(ldr);

    var req:URLRequest = new URLRequest("navBase.swf");
    ldr = new Loader();


    ldr.contentLoaderInfo.addEventListener(Event.COMPLETE,COMPLETEHandler);
     ldr.load(req);
     addChild(ldr);         
}

function COMPLETEHandler(e:Event) {
      Main = ldr.content;
      
      for(var i = 0; i < Main.numChildren; ++i)
      {
             trace(Main.getChildAt(i));
       }
}

ok here we go:
To get all of the objects within the loaded Movieclip i had to wait for the movie clip to finish loading ... yeah makes perfect sense now, but I started this project in FLEX, and there I could assign a name to the container at INIT of the SwfLoader..

Ok after you have got the completed swf all that is left is to save the ldr.content, which was a little odd and explained below.

ldr.content returns [Object MainTimeline], well i can't find anything that is related to what kind of object this is... This is why I have to save to anUntyped variable type. If anyone knows what object type this is that would be great... i hate seeing an Untyped global variable

thanks

[Sleeve]

trace(this is DisplayObjectContainer);//true
trace(this is DisplayObject)//true
trace(this is Sprite)//true
trace(this is MovieClip)//true
trace(this is InteractiveObject)//true 

I suppose you can take your pick with one of these...