using "hitTestPoint" inside a class, won't work

[ThreeDollarBill]

basically, there is a box on stage with an instance name of "box" whose class is called "BoxHitTest"... when i rollover the box, its supposed to trace out: "hitting"... but its not working.

the timeline doesnt contain any code.. the only code is inside the BoxHitTest class...

package
{
    import flash.display.*;
    import flash.events.*;
    
    public class BoxHitTest extends MovieClip
    {
        public function BoxHitTest()
        {
            addEventListener(Event.ENTER_FRAME, runEnterFrame);
        }
        
        function runEnterFrame(event:Event):void
        {
            if(this.hitTestPoint(mouseX, mouseY))
            {
                trace("hitting");
            }
        }
    }
}

what's wrong with my code?

if i type the code on the main timeline below, then it works..

stage.addEventListener(Event.ENTER_FRAME, runEnterFrame);

function runEnterFrame(event:Event):void
{
    if(box.hitTestPoint(mouseX, mouseY))
    {
        trace("hitting");
    }
}

so how should i use hitTestPoint inside a class to make it work properly?

[Mazoonist]

package
{
    import flash.display.*;
    import flash.events.*;
    
    public class BoxHitTest extends MovieClip
    {
        public function BoxHitTest()
        {
            addEventListener(Event.ENTER_FRAME, runEnterFrame);
        }
        
        function runEnterFrame(event:Event):void
        {
            if(this.hitTestPoint(parent.mouseX, parent.mouseY))
            {
                trace("hitting");
            }
        }
    }
}

Notice the addition of "parent" in the mouseX and mouseY properties above. The hitTestPoint function only works with global coordinates. Within your class, mouseX and mouseY (without "parent" in front of them) would be properties of the BoxHitTest class itself, and as such, they are local (not global) coordinates.

When you used the same properties in your timeline code, mouseX and mouseY were properties of the main timeline, and as such, they are global coordinates, and that's why they worked.

[ThreeDollarBill]

ahhh... thanks!!

[henke37]

I recomend taking the coordinates directly from the stage instead of from the parent for the simple reason that the parent are not always the stage.