Accessing variable with String

[kmasterzone]

var constructVarNameForNoNotes:String="noNotesFor"+notesArray[i];
                                {constructVarNameForNoNotes}++;

The value which is stored in constructVarNameForNoNotes is "noNotesFor10" and noNotesFor10 is actually a label to which I want to set some text.

How can I access a variable with String.


Thanks.

[tadster]

//if noNotesFor10 is a variable in the same scope as constructVarNameForNoNotes,
//meaning, if they have the same 'this' ..then:

//..

var constructVarNameForNoNotes:String="noNotesFor"+notesArray[i];

//..
this[constructVarNameForNoNotes] = "somtext";

[drkstr]

Building a numbered strings to create a "list" of items is considered very bad form. It is much better to use an actual list, and only use string accessors for dynamic variable references.

Example:

private var _labelElementList:Array;

private var _labelContentList:Array = ["One", "Two", "Three", "Four"];

override protected function createChildren():void
{
    super.createChildren();

    //instantiate label items and add them as children
    //if this component only has labels as children, then
    //you do not need to keep a seperate array. Instead,
    //use the function to access an indexed child IE
    // this.getChildAt(0)
    _labelElementList = [];
    for( var i:int=0; i < _labelContentList.length; i++)
    {
        var label:Label = new Label();
        _labelElementList.push(label);
        this.addChild(label);
    }
}

//copy the text values to your label elements
override protected function commitProperties():void
{
    super.commitProperties();

    for( var i:int=0; i < _labelContentList.length; i++)
    {
        var label:Label = Label( _labelElementList[i] );
        var text:String = _labelContentList[i];
        label.text = text;
    }
}